Atendiendo el comentario de Jose Fco en el que indica :

<< He podido leer diversos ejemplos de como utilizar e implementar las funciones básicas de acceso al puerto serie principalmente en aplicaciones WinForms, seria posible obtener una esqueleto base en WPF tal como tienes para los anteriores.>>

El siguiente ejemplo, se entiende como ejercicio para realizar la transmisión y recepción de una trama utilizando un temporizador de un segundo en un proyecto WPF, para cerrar el circuito deberás insertar un conector en el puerto serie con un puente entre los pines 2 y 3. Recordad que el uso de ReadLine suspende la ejecucion del thread hasta recibir la sequencia definida en ‘SerialPort.NewLine’.

Partial Public Class Window1


    Delegate Sub Actualizar()
    Private WithEvents Puerto1 As New System.IO.Ports.SerialPort
    Private temporizador As New System.Timers.Timer
    Private Recibidos As String = ""


    Sub New()
        ' Llamada necesaria para el Diseñador de Windows Forms. 
        InitializeComponent()
        Puerto1 = My.Computer.Ports.OpenSerialPort("COM1", 9600)
        AddHandler Puerto1.DataReceived, AddressOf Recepcion
        temporizador.Interval = 1000
        temporizador.Enabled = True
        AddHandler temporizador.Elapsed, AddressOf Peticion
    End Sub

    Private Sub Recepcion()
            Recibidos = Puerto1.ReadLine
            Me.Dispatcher.Invoke(New Actualizar(AddressOf Datos))
    End Sub

    Sub Peticion()
            Puerto1.WriteLine("Saludos!")
    End Sub

    Sub Datos()
            Me.Label1.Content = Recibidos
    End Sub
End Class

Espero que cumpla con tus espectativas.
Saludos,
PepLluis,

Respondiendo una pregunta de los foros, me complace compartir con vosotros el siguiente ejercicio; no sin antes puntualizar que se trata de la puesta en escena de un ejemplo que utilizaría un modulo como “clase estática” donde depositar objetos compartidos dentro de nuestro espacio de aplicación.

Para evitar interpretaciones, este es uno de esos ejemplos que no debe considerarse “modelo” pues su escenario es poco menos que atípico, aclarar que en situaciones similares lo adecuado seria diseñar una clase completa con toda la funcionalidad y acceso, para posteriormente incluirla como propiedad en un modulo. La dificultad se encuentra en la cantidad de código que deberíamos desplegar para realizar una explicación que finalmente terminaría siendo compleja de seguir y entender.

Dicho esto, el siguiente es solo un punto de entrada para las personas que intentan iniciarse en el tema y se encuentran en situaciones como la que expone “Caudiz” en los foros… necesita poder acceder al puerto serie desde dos forms diferentes.

Primero definiríamos el modulo que contendrá toda la lógica de acceso al puerto serie y podría ser algo similar a lo que sigue :

Imports System.IO.Ports
 
Module SerialComm
 
    Private SerialPort1 As New SerialPort
    Private LastFrameRead As String
 
    Public Event DataAvailable()
 
    Sub New()
        SerialPort1.PortName = "COMx"
        SerialPort1.Open()
        AddHandler SerialPort1.DataReceived, AddressOf ReceiveData
    End Sub
 
    Private Sub ReceiveData()
        LastFrameRead += SerialPort1.ReadExisting.ToString()
        RaiseEvent DataAvailable()
    End Sub
 
    Public Function ReadData() As String
        Return LastFrameRead
    End Function
 
    Public Sub WriteData(Frame)
        SerialPort1.Write(Frame)
    End Sub
 
    Public Sub ClearData()
        LastFrameRead = ""
    End Sub
 
End Module

Finalmente incluiríamos el siguiente código para acceder a dicha funcionalidad en este caso desde el ‘Form1’ aunque evidentemente podemos incluirlo desde cualquier otro punto del espacio de nuestra aplicación.

Public Class Form1
 
    Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        AddHandler SerialComm.DataAvailable, AddressOf ReadData
        Form2.Show()
    End Sub
 
    Sub ReadData()
        Me.Label1.Text = SerialComm.ReadData
    End Sub
 
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        SerialComm.WriteData("Hola :-) from 1")
    End Sub
End Class

Public Class Form2
 
    Private Sub Form2_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        AddHandler SerialComm.DataAvailable, AddressOf ReadData
    End Sub
 
    Sub ReadData()
        Me.Label1.Text = SerialComm.ReadData
    End Sub
 
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        SerialComm.WriteData("Hola :-) from 2")
    End Sub
 
End Class

Espero vuestros comentarios y que a partir de esta idea, podáis construir de forma robusta la implementación de vuestra solucion.
Saludos,
PepLluis,

Atendiendo la petición de un lector pidiéndome el código completo…

Public Class Form1
    ''' <summary>
    ''' Complete code to test the frame reading values sample (last post)
    ''' PepLluis, 11/10/2011
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        ' Simulate string frame with values
        Dim frame = "{W111}{M222}{F333}{S444}"
        ' define Label and textboxes
        Dim Label1 As New Label With
            {.Name = "Label1", .AutoSize = True, .Location = New Drawing.Point(12, 10), .Text = "Frame :" + frame}
        Dim TextBox1 As New TextBox With {.Name = "TextBox1", .Width = 60, .Location = New Drawing.Point(12, 30)}
        Dim TextBox2 As New TextBox With {.Name = "TextBox2", .Width = 60, .Location = New Drawing.Point(12, 50)}
        Dim TextBox3 As New TextBox With {.Name = "TextBox3", .Width = 60, .Location = New Drawing.Point(12, 70)}
        Dim TextBox4 As New TextBox With {.Name = "TextBox4", .Width = 60, .Location = New Drawing.Point(12, 90)}
        ' add controls to form
        Me.Controls.AddRange({Label1, TextBox1, TextBox2, TextBox3, TextBox4})
        ' define char as fields separators and values iden
        Dim separators As Char() = {"{", "W", "M", "S", "F", "}"}
        ' get fields
        Dim fields As String() = (
              From f As String In frame.Split(separators)
              Where f.Length > 0
            ).ToArray
        ' get textBoxes names
        Dim textBoxesNames() =
            (
                From Tbn As Object In Me.Controls
                Where Tbn.GetType.Name = "TextBox"
                Select CType(Tbn, TextBox).Name Order By Name
            ).ToArray
        ' assign values to textboxes
        For Index As Integer = 0 To textBoxesNames.Count - 1
            Me.Controls.Item(textBoxesNames(Index)).Text = fields(Index)
        Next
    End Sub
End Class
 

Regards! :-)  
PepLluis,     

 Visual basic = 

Public Class Form1
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Dim frame = "{W111}{M22}{F33}{S44}"
        Dim separators As Char() = {"{", "W", "M", "S", "F", "}"}
        Dim fields As String() = (From f As String In frame.Split(separators) Where f.Length > 0).ToArray
        Dim textBoxesNames() = (From Tbn As Object In Me.Controls Where Tbn.GetType.Name = "TextBox" Select CType(Tbn, TextBox).Name Order By Name).ToArray
        For Index As Integer = 0 To textBoxesNames.Count - 1
            Me.Controls.Item(textBoxesNames(Index)).Text = fields(Index)
        Next
    End Sub
End Class

C# =

using System;
using System.Linq;
using System.Windows.Forms;
 
namespace WindowsFormsApplication1
{
    public partial class Form1 : Form
    {
        public Form1()
        {
            InitializeComponent();
        }
 
        private void Form1_Load(object sender, EventArgs e)
        {
            string frame = "{W111}{M22}{F33}{S44}";
            char[] separators = new char[] { '{', 'W', 'M', 'S', 'F', '}' };
            string[] fields = (from string f in frame.Split(separators) where f.Length > 0 select f).ToArray();
            string[] textBoxesNames = (from Tbn in this.Controls.OfType<TextBox>() where Tbn.GetType().Name == "TextBox" orderby Tbn.Name select Tbn.Name).ToArray();
            for (int Index = 0; Index < textBoxesNames.Count(); Index++)
            {
                this.Controls[textBoxesNames[Index]].Text = fields[Index];
            }
        }
    }
}

Regards,
PepLluis,